Notice: Undefined index: moes_p in /home/elpanov/elpanov.com/docs/index.php(3) : eval()'d code on line 1
ElpanovEvgeniy | Временные линии

Новая версия сайта, доступна здесь.




Временные линии





eea-vec.gif (133 Кб)



;;	eea-vec.lsp
(defun eea-vec (/ PT PTLIST)
               ;|
*****************************************************************************************

by ElpanovEvgeniy

Библиотечная функция.
Программа, позволяет рисовать временные ломанные линии на экране.

Программа возвращает список точек, в последовательности указания.

Дата создания      19.10.2005
последняя редакция ---
*****************************************************************************************


Library function.
The program, allows to draw temporary lines on the screen.

The program returns the list of points, in sequence of instructions.

Date of creation   19.10.2005
Last edition       ---

(eea-vec)
*****************************************************************************************
|;
 (setq PTLIST (list (setq PT (getpoint "\n Specify the first point  "))))
 (princ "\n Specify the following point  ")
 (princ)
 (while (setq PT (progn (while (and (setq PT (grread 5)) (= (car PT) 5))
                         (redraw)
                         (mapcar (function (lambda (x1 x2) (grdraw x1 x2 3 5)))
                                 (cons (cadr PT) PTLIST)
                                 PTLIST
                         ) ;_  mapcar
                        ) ;_  while
                        (if (listp (cadr PT))
                         (cadr PT)
                        ) ;_  if
                 ) ;_  progn
        ) ;_  setq
  (setq PTLIST (cons PT PTLIST))
 ) ;_  while
) ;_  defun

;|«Visual LISP© Format Options»
(80 1 2 2 T " " 80 60 0 0 0 nil nil nil T)
;*** DO NOT add text below the comment! ***|;