ElpanovEvgeniy | Линия 45

Линия 45

;;	line-45.lsp
(defun line-45 (/ GR LST PT)
               ;|
*****************************************************************************************

by ElpanovEvgeniy

Демонстрационная учебная программа.
Программа позволяет рисовать линию, с заранее заданным углом.
Работа программы, подобна команде "_line" с опцией "<45"
В программе используется прямое редактирование DXF кодов линии.

Дата создания      03.22.2005
последняя редакция ---
*****************************************************************************************


Demonstration, educational code
The program allows to draw a line, with in advance set angle.
Program job, is similar to "_line" command with an option "<45 "
In the program direct editing DXF of codes of an line.

Date of creation   03.22.2005
Last edition       ---

(line-45)
*****************************************************************************************
|;
 (setq
  lst (entget
       (entmakex
        (list '(0 . "LINE")
              (cons 8 (getvar "CLAYER"))
              (cons 10 (setq pt (getpoint "\n Specify the first point  ")))
              (cons 11 pt)
        ) ;_  list
       ) ;_  entmakex
      ) ;_  entget
 ) ;_  setq
 (princ "\n Specify the second point  ")
 (while (and (setq gr (grread 5)) (= (car gr) 5))
  (entmod (subst (cons 11 (polar pt (/ pi 4) (distance pt (cadr gr))))
                 (assoc 11 lst)
                 lst
          ) ;_  subst
  ) ;_  entmod
  (entupd (cdr (assoc -1 lst)))
 ) ;_  while
) ;_  defun



;|«Visual LISP© Format Options»
(80 1 2 2 T " " 80 60 0 0 0 nil nil nil T)
;*** DO NOT add text below the comment! ***|;
Великому и могучему языку посвящается...

Линия 45
